本文整理汇总了VB.NET中System.Threading.Tasks.Parallel.For方法的典型用法代码示例。如果您正苦于以下问题：VB.NET Parallel.For方法的具体用法？VB.NET Parallel.For怎么用？VB.NET Parallel.For使用的例子？那么, 这里精选的方法代码示例或许可以为您提供帮助。您也可以进一步了解该方法所在类System.Threading.Tasks.Parallel的用法示例。
在下文中一共展示了Parallel.For方法的6个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于系统推荐出更棒的VB.NET代码示例。
示例1: Example
' 导入命名空间
Imports System.Threading
Imports System.Threading.Tasks
Module Example
Public Sub Main()
Dim rnd As New Random()
Dim breakIndex As Integer = rnd.Next(1, 11)
Dim lowest As New Nullable(Of Long)()
Console.WriteLine("Will call Break at iteration {0}", breakIndex)
Console.WriteLine()
Dim result = Parallel.For(1, 101, Sub(i, state)
Console.WriteLine("Beginning iteration {0}", i)
Dim delay As Integer
Monitor.Enter(rnd)
delay = rnd.Next(1, 1001)
Monitor.Exit(rnd)
Thread.Sleep(delay)
If state.ShouldExitCurrentIteration Then
If state.LowestBreakIteration < i Then
Return
End If
End If
If i = breakIndex Then
Console.WriteLine("Break in iteration {0}", i)
state.Break()
If state.LowestBreakIteration.HasValue Then
If lowest < state.LowestBreakIteration Then
lowest = state.LowestBreakIteration
Else
lowest = state.LowestBreakIteration
End If
End If
End If
Console.WriteLine("Completed iteration {0}", i)
End Sub )
Console.WriteLine()
If lowest.HasValue Then
Console.WriteLine("Lowest Break Iteration: {0}", lowest)
Else
Console.WriteLine("No lowest break iteration.")
End If
End Sub
End Module输出：
Will call Break at iteration 8 Beginning iteration 1 Beginning iteration 13 Beginning iteration 97 Beginning iteration 25 Beginning iteration 49 Beginning iteration 37 Beginning iteration 85 Beginning iteration 73 Beginning iteration 61 Completed iteration 85 Beginning iteration 86 Completed iteration 61 Beginning iteration 62 Completed iteration 86 Beginning iteration 87 Completed iteration 37 Beginning iteration 38 Completed iteration 38 Beginning iteration 39 Completed iteration 25 Beginning iteration 26 Completed iteration 26 Beginning iteration 27 Completed iteration 73 Beginning iteration 74 Completed iteration 62 Beginning iteration 63 Completed iteration 39 Beginning iteration 40 Completed iteration 40 Beginning iteration 41 Completed iteration 13 Beginning iteration 14 Completed iteration 1 Beginning iteration 2 Completed iteration 97 Beginning iteration 98 Completed iteration 49 Beginning iteration 50 Completed iteration 87 Completed iteration 27 Beginning iteration 28 Completed iteration 50 Beginning iteration 51 Beginning iteration 88 Completed iteration 14 Beginning iteration 15 Completed iteration 15 Completed iteration 2 Beginning iteration 3 Beginning iteration 16 Completed iteration 63 Beginning iteration 64 Completed iteration 74 Beginning iteration 75 Completed iteration 41 Beginning iteration 42 Completed iteration 28 Beginning iteration 29 Completed iteration 29 Beginning iteration 30 Completed iteration 98 Beginning iteration 99 Completed iteration 64 Beginning iteration 65 Completed iteration 42 Beginning iteration 43 Completed iteration 88 Beginning iteration 89 Completed iteration 51 Beginning iteration 52 Completed iteration 16 Beginning iteration 17 Completed iteration 43 Beginning iteration 44 Completed iteration 44 Beginning iteration 45 Completed iteration 99 Beginning iteration 4 Completed iteration 3 Beginning iteration 8 Completed iteration 4 Beginning iteration 5 Completed iteration 52 Beginning iteration 53 Completed iteration 75 Beginning iteration 76 Completed iteration 76 Beginning iteration 77 Completed iteration 65 Beginning iteration 66 Completed iteration 5 Beginning iteration 6 Completed iteration 89 Beginning iteration 90 Completed iteration 30 Beginning iteration 31 Break in iteration 8 Completed iteration 8 Completed iteration 6 Beginning iteration 7 Completed iteration 7 Lowest Break Iteration: 8
示例2: Example
' 导入命名空间
Imports System.Threading.Tasks
Module Example
Public Sub Main()
Dim result As ParallelLoopResult = Parallel.For(0, 100, Sub(ctr)
Dim rnd As New Random(ctr * 100000)
Dim bytes(99) As Byte
rnd.NextBytes(bytes)
Dim sum As Integer
For Each byt In bytes
sum += byt
Next
Console.WriteLine("Iteration {0,2}: {1:N0}", ctr, sum)
End Sub)
Console.WriteLine("Result: {0}", If(result.IsCompleted, "Completed Normally",
String.Format("Completed to {0}", result.LowestBreakIteration)))
End Sub
End Module
' The following is a portion of the output displayed by the example:
' Iteration 0: 12,509
' Iteration 50: 12,823
' Iteration 51: 11,275
' Iteration 52: 12,531
' Iteration 1: 13,007
' Iteration 53: 13,799
' Iteration 4: 12,945
' Iteration 2: 13,246
' Iteration 54: 13,008
' Iteration 55: 12,727
' Iteration 56: 13,223
' Iteration 57: 13,717
' Iteration 5: 12,679
' Iteration 3: 12,455
' Iteration 58: 12,669
' Iteration 59: 11,882
' Iteration 6: 13,167
' ...
' Iteration 92: 12,275
' Iteration 93: 13,282
' Iteration 94: 12,745
' Iteration 95: 11,957
' Iteration 96: 12,455
' Result: Completed Normally示例3: LoopCancellation
' 导入命名空间
Imports System.Threading
Imports System.Threading.Tasks
Module LoopCancellation
' Demonstrated features:
' CancellationTokenSource
' Parallel.For()
' ParallelOptions
' ParallelLoopResult
' Expected results:
' An iteration for each argument value (0, 1, 2, 3, 4, 5, 6, 7, 8, 9) is executed.
' The order of execution of the iterations is undefined.
' The iteration when i=2 cancels the loop.
' Some iterations may bail out or not start at all; because they are temporally executed in unpredictable order,
' it is impossible to say which will start/complete and which won't.
' At the end, an OperationCancelledException is surfaced.
' Documentation:
' http://msdn.microsoft.com/library/system.threading.cancellationtokensource(VS.100).aspx
Private Sub Main()
Dim cancellationSource As New CancellationTokenSource()
Dim options As New ParallelOptions()
options.CancellationToken = cancellationSource.Token
Try
Dim loopResult As ParallelLoopResult = _
Parallel.For(0, 10, options, Sub(i, loopState)
Console.WriteLine("Start Thread={0}, i={1}", Thread.CurrentThread.ManagedThreadId, i)
' Simulate a cancellation of the loop when i=2
If i = 2 Then
cancellationSource.Cancel()
End If
' Simulates a long execution
For j As Integer = 0 To 9
Thread.Sleep(1 * 200)
' check to see whether or not to continue
If loopState.ShouldExitCurrentIteration Then
Exit Sub
End If
Next
Console.WriteLine("Finish Thread={0}, i={1}", Thread.CurrentThread.ManagedThreadId, i)
End Sub)
If loopResult.IsCompleted Then
Console.WriteLine("All iterations completed successfully. THIS WAS NOT EXPECTED.")
End If
Catch e As AggregateException
' No exception is expected in this example, but if one is still thrown from a task,
' it will be wrapped in AggregateException and propagated to the main thread.
Console.WriteLine("An action has thrown an AggregateException. THIS WAS NOT EXPECTED." & vbLf & "{0}", e)
Catch e As OperationCanceledException
' Catching the cancellation exception
Console.WriteLine("An iteration has triggered a cancellation. THIS WAS EXPECTED." & vbLf & "{0}", e)
Finally
cancellationSource.Dispose()
End Try
End Sub
End Module示例4: ParallelForDemo
' 导入命名空间
Imports System.Threading
Imports System.Threading.Tasks
Module ParallelForDemo
' Demonstrated features:
' Parallel.For()
' ParallelOptions
' Expected results:
' An iteration for each argument value (0, 1, 2, 3, 4, 5, 6, 7, 8, 9) is executed.
' The order of execution of the iterations is undefined.
' Verify that no more than two threads have been used for the iterations.
' Documentation:
' http://msdn.microsoft.com/library/system.threading.tasks.parallel.for(VS.100).aspx
Sub Main()
Dim options As New ParallelOptions()
options.MaxDegreeOfParallelism = 2 ' -1 is for unlimited. 1 is for sequential.
Try
Parallel.For(0, 9, options, Sub(i)
Console.WriteLine("Thread={0}, i={1}", Thread.CurrentThread.ManagedThreadId, i)
End Sub)
Catch e As AggregateException
' No exception is expected in this example, but if one is still thrown from a task,
' it will be wrapped in AggregateException and propagated to the main thread.
Console.WriteLine("Parallel.For has thrown the following (unexpected) exception:" & vbLf & "{0}", e)
End Try
End Sub
End Module示例5: SchedulerDemo
' 导入命名空间
Imports System.Collections.Concurrent
Imports System.Threading
Imports System.Threading.Tasks
Module SchedulerDemo
' Demonstrated features:
' TaskScheduler
' BlockingCollection
' Parallel.For()
' ParallelOptions
' Expected results:
' An iteration for each argument value (0, 1, 2, 3, 4, 5, 6, 7, 8, 9) is executed.
' The TwoThreadTaskScheduler employs 2 threads on which iterations may be executed in a random order.
' A task is internally created for each thread of the task scheduler (plus an aditional internal task).
' Thus a scheduler thread may execute multiple iterations.
' Documentation:
' http://msdn.microsoft.com/library/system.threading.tasks.taskscheduler(VS.100).aspx
' http://msdn.microsoft.com/library/dd997413(VS.100).aspx
' More information:
' http://blogs.msdn.com/pfxteam/archive/2009/09/22/9898090.aspx
Sub Main()
Dim options As New ParallelOptions()
' Construct and associate a custom task scheduler
options.TaskScheduler = New TwoThreadTaskScheduler()
Try
Parallel.For(0, 10, options, Sub(i, localState)
Console.WriteLine("i={0}, Task={1}, Thread={2}", i, Task.CurrentId, Thread.CurrentThread.ManagedThreadId)
End Sub)
Catch e As AggregateException
' No exception is expected in this example, but if one is still thrown from a task,
' it will be wrapped in AggregateException and propagated to the main thread.
Console.WriteLine("An iteration has thrown an exception. THIS WAS NOT EXPECTED." & vbLf & "{0}", e)
End Try
End Sub
' This scheduler schedules all tasks on (at most) two threads
Private NotInheritable Class TwoThreadTaskScheduler
Inherits TaskScheduler
Implements IDisposable
' The runtime decides how many tasks to create for the given set of iterations, loop options, and scheduler's max concurrency level.
' Tasks will be queued in this collection
Private _tasks As New BlockingCollection(Of Task)()
' Maintain an array of threads. (Feel free to bump up _n.)
Private ReadOnly _n As Integer = 2
Private _threads As Thread()
Public Sub New()
_threads = New Thread(_n - 1) {}
' Create unstarted threads based on the same inline delegate
For i As Integer = 0 To _n - 1
_threads(i) = New Thread(Sub()
' The following loop blocks until items become available in the blocking collection.
' Then one thread is unblocked to consume that item.
For Each task In _tasks.GetConsumingEnumerable()
TryExecuteTask(task)
Next
End Sub)
' Start each thread
_threads(i).IsBackground = True
_threads(i).Start()
Next
End Sub
' This method is invoked by the runtime to schedule a task
Protected Overloads Overrides Sub QueueTask(ByVal task As Task)
_tasks.Add(task)
End Sub
' The runtime will probe if a task can be executed in the current thread.
' By returning false, we direct all tasks to be queued up.
Protected Overloads Overrides Function TryExecuteTaskInline(ByVal task As Task, ByVal taskWasPreviouslyQueued As Boolean) As Boolean
Return False
End Function
Public Overloads Overrides ReadOnly Property MaximumConcurrencyLevel() As Integer
Get
Return _n
End Get
End Property
Protected Overloads Overrides Function GetScheduledTasks() As IEnumerable(Of Task)
Return _tasks.ToArray()
End Function
' Dispose is not thread-safe with other members.
' It may only be used when no more tasks will be queued
' to the scheduler. This implementation will block
' until all previously queued tasks have completed.
Public Sub Dispose() Implements IDisposable.Dispose
If _threads IsNot Nothing Then
_tasks.CompleteAdding()
For i As Integer = 0 To _n - 1
_threads(i).Join()
_threads(i) = Nothing
Next
_threads = Nothing
_tasks.Dispose()
_tasks = Nothing
End If
End Sub
End Class
End Module示例6: ThreadLocalForWithOptions
' 导入命名空间
Imports System.Threading
Imports System.Threading.Tasks
Module ThreadLocalForWithOptions
' The number of parallel iterations to perform.
Const N As Integer = 1000000
Sub Main()
' The result of all thread-local computations.
Dim result As Integer = 0
' This example limits the degree of parallelism to four.
' You might limit the degree of parallelism when your algorithm
' does not scale beyond a certain number of cores or when you
' enforce a particular quality of service in your application.
Parallel.For(0, N, New ParallelOptions With {.MaxDegreeOfParallelism = 4},
Function()
' Initialize the local states
Return 0
End Function,
Function(i, loopState, localState)
' Accumulate the thread-local computations in the loop body
Return localState + Compute(i)
End Function,
Sub(localState)
' Combine all local states
Interlocked.Add(result, localState)
End Sub
)
' Print the actual and expected results.
Console.WriteLine("Actual result: {0}. Expected 1000000.", result)
End Sub
' Simulates a lengthy operation.
Function Compute(ByVal n As Integer) As Integer
For i As Integer = 0 To 10000
Next
Return 1
End Function
End Module