本文整理汇总了VB.NET中System.Collections.Specialized.NameObjectCollectionBase.BaseRemoveAt方法的典型用法代码示例。如果您正苦于以下问题：VB.NET NameObjectCollectionBase.BaseRemoveAt方法的具体用法？VB.NET NameObjectCollectionBase.BaseRemoveAt怎么用？VB.NET NameObjectCollectionBase.BaseRemoveAt使用的例子？那么, 这里精选的方法代码示例或许可以为您提供帮助。您也可以进一步了解该方法所在类System.Collections.Specialized.NameObjectCollectionBase的用法示例。
在下文中一共展示了NameObjectCollectionBase.BaseRemoveAt方法的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于系统推荐出更棒的VB.NET代码示例。
示例1: MyCollection
' 导入命名空间
Imports System.Collections
Imports System.Collections.Specialized
Public Class MyCollection
Inherits NameObjectCollectionBase
Private _de As New DictionaryEntry()
' Gets a key-and-value pair (DictionaryEntry) using an index.
Default Public ReadOnly Property Item(index As Integer) As DictionaryEntry
Get
_de.Key = Me.BaseGetKey(index)
_de.Value = Me.BaseGet(index)
Return _de
End Get
End Property
' Adds elements from an IDictionary into the new collection.
Public Sub New(d As IDictionary)
Dim de As DictionaryEntry
For Each de In d
Me.BaseAdd(CType(de.Key, [String]), de.Value)
Next de
End Sub
' Removes an entry with the specified key from the collection.
Overloads Public Sub Remove(key As [String])
Me.BaseRemove(key)
End Sub
' Removes an entry in the specified index from the collection.
Overloads Public Sub Remove(index As Integer)
Me.BaseRemoveAt(index)
End Sub
End Class
Public Class SamplesNameObjectCollectionBase
Public Shared Sub Main()
' Creates and initializes a new MyCollection instance.
Dim d = New ListDictionary()
d.Add("red", "apple")
d.Add("yellow", "banana")
d.Add("green", "pear")
Dim myCol As New MyCollection(d)
Console.WriteLine("Initial state of the collection (Count = {0}):", myCol.Count)
PrintKeysAndValues(myCol)
' Removes an element at a specific index.
myCol.Remove(1)
Console.WriteLine("After removing the element at index 1 (Count = {0}):", myCol.Count)
PrintKeysAndValues(myCol)
' Removes an element with a specific key.
myCol.Remove("red")
Console.WriteLine("After removing the element with the key ""red"" (Count = {0}):", myCol.Count)
PrintKeysAndValues(myCol)
End Sub
Public Shared Sub PrintKeysAndValues(myCol As MyCollection)
Dim i As Integer
For i = 0 To myCol.Count - 1
Console.WriteLine("[{0}] : {1}, {2}", i, myCol(i).Key, myCol(i).Value)
Next i
End Sub
End Class开发者ID:VB.NET开发者，项目名称:System.Collections.Specialized，代码行数:72，代码来源:NameObjectCollectionBase.BaseRemoveAt
输出：
Initial state of the collection (Count = 3): [0] : red, apple [1] : yellow, banana [2] : green, pear After removing the element at index 1 (Count = 2): [0] : red, apple [1] : green, pear After removing the element with the key "red" (Count = 1): [0] : green, pear