VB.NET Application.ThreadException事件代码示例

Private newThread As Thread = Nothing

' Starts the application. 
<SecurityPermission(SecurityAction.Demand, Flags:=SecurityPermissionFlag.ControlAppDomain)> _
Public Shared Sub Main()
    ' Add the event handler for handling UI thread exceptions to the event.
    AddHandler Application.ThreadException, AddressOf ErrorHandlerForm.Form1_UIThreadException

    ' Set the unhandled exception mode to force all Windows Forms errors to go through
    ' our handler.
    Application.SetUnhandledExceptionMode(UnhandledExceptionMode.CatchException)

    ' Add the event handler for handling non-UI thread exceptions to the event. 
    AddHandler AppDomain.CurrentDomain.UnhandledException, AddressOf CurrentDomain_UnhandledException

    ' Runs the application.
    Application.Run(New ErrorHandlerForm())
End Sub


' Programs the button to throw an exception when clicked.
Private Sub button1_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles button1.Click
    Throw New ArgumentException("The parameter was invalid")
End Sub

' Start a new thread, separate from Windows Forms, that will throw an exception.
Private Sub button2_Click(ByVal sender As Object, ByVal e As System.EventArgs) Handles button2.Click
    Dim newThreadStart As New ThreadStart(AddressOf newThread_Execute)
    newThread = New Thread(newThreadStart)
    newThread.Start()
End Sub


' The thread we start up to demonstrate non-UI exception handling. 
Sub newThread_Execute()
    Throw New Exception("The method or operation is not implemented.")
End Sub


' Handle the UI exceptions by showing a dialog box, and asking the user whether
' or not they wish to abort execution.
Private Shared Sub Form1_UIThreadException(ByVal sender As Object, ByVal t As ThreadExceptionEventArgs)
    Dim result As System.Windows.Forms.DialogResult = _
        System.Windows.Forms.DialogResult.Cancel
    Try
        result = ShowThreadExceptionDialog("Windows Forms Error", t.Exception)
    Catch
        Try
            MessageBox.Show("Fatal Windows Forms Error", _
                "Fatal Windows Forms Error", MessageBoxButtons.AbortRetryIgnore, MessageBoxIcon.Stop)
        Finally
            Application.Exit()
        End Try
    End Try

    ' Exits the program when the user clicks Abort.
    If result = DialogResult.Abort Then
        Application.Exit()
    End If
End Sub

' Handle the UI exceptions by showing a dialog box, and asking the user whether
' or not they wish to abort execution.
' NOTE: This exception cannot be kept from terminating the application - it can only 
' log the event, and inform the user about it. 
Private Shared Sub CurrentDomain_UnhandledException(ByVal sender As Object, _
ByVal e As UnhandledExceptionEventArgs)
    Try
        Dim ex As Exception = CType(e.ExceptionObject, Exception)
        Dim errorMsg As String = "An application error occurred. Please contact the adminstrator " & _
            "with the following information:" & ControlChars.Lf & ControlChars.Lf

        ' Since we can't prevent the app from terminating, log this to the event log.
        If (Not EventLog.SourceExists("ThreadException")) Then
            EventLog.CreateEventSource("ThreadException", "Application")
        End If

        ' Create an EventLog instance and assign its source.
        Dim myLog As New EventLog()
        myLog.Source = "ThreadException"
        myLog.WriteEntry((errorMsg + ex.Message & ControlChars.Lf & ControlChars.Lf & _
            "Stack Trace:" & ControlChars.Lf & ex.StackTrace))
    Catch exc As Exception
        Try
            MessageBox.Show("Fatal Non-UI Error", "Fatal Non-UI Error. Could not write the error to the event log. " & _
                "Reason: " & exc.Message, MessageBoxButtons.OK, MessageBoxIcon.Stop)
        Finally
            Application.Exit()
        End Try
    End Try
End Sub


' Creates the error message and displays it.
Private Shared Function ShowThreadExceptionDialog(ByVal title As String, ByVal e As Exception) As DialogResult
    Dim errorMsg As String = "An application error occurred. Please contact the adminstrator " & _
 "with the following information:" & ControlChars.Lf & ControlChars.Lf
    errorMsg = errorMsg & e.Message & ControlChars.Lf & _
 ControlChars.Lf & "Stack Trace:" & ControlChars.Lf & e.StackTrace

    Return MessageBox.Show(errorMsg, title, MessageBoxButtons.AbortRetryIgnore, MessageBoxIcon.Stop)
End Function

' 导入命名空间
Imports System.Windows.Forms

Public Class Form1
    Inherits System.Windows.Forms.Form
    Friend WithEvents button4 As System.Windows.Forms.Button
    Friend WithEvents button3 As System.Windows.Forms.Button
    Friend WithEvents button2 As System.Windows.Forms.Button
    Friend WithEvents button1 As System.Windows.Forms.Button

    Public Sub New()
        MyBase.New()

        Me.button4 = New System.Windows.Forms.Button()
        Me.button3 = New System.Windows.Forms.Button()
        Me.button2 = New System.Windows.Forms.Button()
        Me.button1 = New System.Windows.Forms.Button()
        Me.SuspendLayout()
        '
        Me.button4.Location = New System.Drawing.Point(24, 127)
        Me.button4.Name = "button4"
        Me.button4.Size = New System.Drawing.Size(144, 23)
        Me.button4.TabIndex = 7
        Me.button4.Text = "Show MessageBox"
        '
        Me.button3.Location = New System.Drawing.Point(24, 90)
        Me.button3.Name = "button3"
        Me.button3.Size = New System.Drawing.Size(144, 23)
        Me.button3.TabIndex = 6
        Me.button3.Text = "Throw Exception"
        '
        Me.button2.Location = New System.Drawing.Point(24, 53)
        Me.button2.Name = "button2"
        Me.button2.Size = New System.Drawing.Size(144, 23)
        Me.button2.TabIndex = 5
        Me.button2.Text = "Application.ExitThread"
        '
        Me.button1.Location = New System.Drawing.Point(24, 16)
        Me.button1.Name = "button1"
        Me.button1.Size = New System.Drawing.Size(144, 23)
        Me.button1.TabIndex = 4
        Me.button1.Text = "Application.Exit"
        '
        Me.AutoScaleBaseSize = New System.Drawing.Size(5, 13)
        Me.ClientSize = New System.Drawing.Size(192, 166)
        Me.Controls.AddRange(New System.Windows.Forms.Control() {Me.button4, Me.button3, Me.button2, Me.button1})
        Me.ResumeLayout(False)

    End Sub

    Shared Sub App_Exit(ByVal sender As Object, ByVal e As EventArgs)
        System.Diagnostics.Debug.WriteLine("App_Exit")
    End Sub

    Shared Sub App_Idle(ByVal sender As Object, ByVal e As EventArgs)
        System.Diagnostics.Debug.WriteLine("App_Idle")
    End Sub

    Shared Sub App_ThreadingException(ByVal sender As Object, ByVal e As System.Threading.ThreadExceptionEventArgs)
        System.Diagnostics.Debug.WriteLine("App_ThreadException")
        Dim msg As String = "A problem has occurred in this application." & vbCrLf & vbCrLf & _
            vbTab & e.Exception.Message & vbCrLf & vbCrLf & _
            "Would you like to continue the application so that " & vbCrLf & _
            "you can save your work?"
        Dim res As DialogResult = MessageBox.Show(msg, "Unexpected Error", MessageBoxButtons.YesNo)
        If res = System.Windows.Forms.DialogResult.Yes Then Exit Sub
        Application.Exit()
    End Sub

    Shared Sub DumpThreadID(ByVal name As String)
        System.Diagnostics.Debug.WriteLine(name & " thread id= " & System.AppDomain.GetCurrentThreadId().ToString())
    End Sub

    Shared Sub DummyThreadStart()
        DumpThreadID("Dummy Thread")
        AddHandler Application.ThreadExit, New EventHandler(AddressOf App_ThreadExit)
    End Sub

    Shared Sub Main()
        AddHandler Application.ThreadException, New System.Threading.ThreadExceptionEventHandler(AddressOf App_ThreadingException)
        AddHandler Application.Idle, New EventHandler(AddressOf App_Idle)
        AddHandler Application.ThreadExit, New EventHandler(AddressOf App_ThreadExit)
        AddHandler Application.ApplicationExit, New EventHandler(AddressOf App_Exit)

        DumpThreadID("UI Thread")
        Dim dummythread As System.Threading.Thread = New System.Threading.Thread(New System.Threading.ThreadStart(AddressOf DummyThreadStart))
        dummythread.Start()

        Application.Run(New Form1())

    End Sub

    Shared Sub App_ThreadExit(ByVal sender As Object, ByVal e As EventArgs)
        System.Diagnostics.Debug.WriteLine("App_ThreadExit on thread id= " & System.AppDomain.GetCurrentThreadId().ToString())
    End Sub

    Private Sub button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles button1.Click
        Application.Exit()
    End Sub
    Private Sub button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles button2.Click
        Application.ExitThread()
    End Sub
    Private Sub button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles button3.Click
        Throw New System.IO.FileLoadException()
    End Sub

End Class