VB.NET SoapAttributeAttribute构造函数代码示例

' 导入命名空间
Imports System.IO
Imports System.Xml
Imports System.Xml.Serialization


Public Class Group
   ' This attribute will be overridden.
   <SoapAttribute (Namespace: = "http://www.cpandl.com")> _
   Public GroupName As String 
   
End Class

public class Run
   Public Shared Sub Main()
   
      Dim test  As Run = new Run()
      test.SerializeOverride("SoapOveride.xml")
   End Sub
   
   Public Sub SerializeOverride(filename As String )
      ' Create an instance of the XmlSerializer class
      ' that overrides the serialization.
      Dim overRideSerializer  As XmlSerializer = _
      CreateOverrideSerializer()

      ' Writing the file requires a TextWriter.
      Dim writer As TextWriter = new StreamWriter(filename)

      ' Create an instance of the class that will be serialized.
      Dim myGroup As Group = new Group()

      ' Set the object properties.
      myGroup.GroupName = ".NET"

      ' Serialize the class, and close the TextWriter.
      overRideSerializer.Serialize(writer, myGroup)
       writer.Close()
   End Sub


   Private Function CreateOverrideSerializer() As XmlSerializer 
    
      Dim mySoapAttributeOverrides As SoapAttributeOverrides = _
      New SoapAttributeOverrides()
      Dim mySoapAttributes As SoapAttributes = New SoapAttributes()
      ' Create a new SoapAttributeAttribute to override the 
      ' one applied to the Group class. The resulting XML 
      ' stream will use the new namespace and attribute name.
      Dim mySoapAttribute As SoapAttributeAttribute = _
      New SoapAttributeAttribute()
      mySoapAttribute.AttributeName = "TeamName"
      ' Change the Namespace.
      mySoapAttribute.Namespace = "http://www.cohowinery"

      mySoapAttributes.SoapAttribute = mySoapAttribute
      mySoapAttributeOverrides. _
      Add(GetType(Group), "GroupName" ,mySoapAttributes)
    
      Dim myMapping  As XmlTypeMapping = (new SoapReflectionImporter _
      (mySoapAttributeOverrides)).ImportTypeMapping(GetType(Group))
    
      Dim ser As XmlSerializer = new XmlSerializer(myMapping)
      CreateOverrideSerializer = ser
   End Function

End Class
'<?xml version="1.0" encoding="utf-8" ?> 
'<Group xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
'xmlns:xsd="http://www.w3.org/2001/XMLSchema" n1:TeamName=".NET" 
'xmlns:n1="http://www.cohowinery" />

' 导入命名空间
Imports System.IO
Imports System.Text
Imports System.Xml
Imports System.Xml.Serialization
Imports System.Xml.Schema

<SoapInclude(GetType(Vehicle))> _
Public Class Group

   <SoapAttribute (Namespace:= "http:'www.cpandl.com")> _
   Public GroupName As String    
   <SoapAttribute(DataType:= "base64Binary")> _
   Public GroupNumber() As  Byte 

   <SoapAttribute(DataType:= "date", AttributeName:= "CreationDate")> _
   Public Today As DateTime 
   <SoapElement(DataType:= "nonNegativeInteger", _
   ElementName:= "PosInt")> _
   Public PostitiveInt As String 

   Public GroupVehicle As Vehicle 
End Class
  
Public Class Vehicle
   Public licenseNumber As String 
End Class

Public Class Run

   Shared Sub Main()
   
      Dim test As Run = New Run()
      test.SerializeObject("SoapAtts.xml")
      test.DeserializeObject("SoapAtts.xml")
   End Sub
   
   Public Sub SerializeObject(filename As String)
   
      ' Create an instance of the XmlSerializer Class that
      ' can generate encoded SOAP messages.
      Dim mySerializer As XmlSerializer  =  ReturnSOAPSerializer()

      Dim myGroup As Group = MakeGroup()
      ' Writing the file requires a TextWriter.
      Dim writer As XmlTextWriter = _
      New XmlTextWriter(filename, Encoding.UTF8)
      writer.Formatting = Formatting.Indented
      writer.WriteStartElement("wrapper")
      ' Serialize the Class, and close the TextWriter.
      mySerializer.Serialize(writer, myGroup)
      writer.WriteEndElement()
      writer.Close()
   End Sub

   Private Function MakeGroup() As Group 
      ' Create an instance of the Class that will be serialized.
      Dim myGroup As Group = New Group()

      ' Set the object properties.
      myGroup.GroupName = ".NET"

      Dim hexByte() As Byte= New Byte(1){Convert.ToByte(100), _
      Convert.ToByte(50)}
      myGroup.GroupNumber = hexByte

      Dim myDate As DateTime = New DateTime(2002,5,2)
      myGroup.Today = myDate
      myGroup.PostitiveInt= "10000"
      myGroup.GroupVehicle = New Vehicle()
      myGroup.GroupVehicle.licenseNumber="1234"
      return myGroup
   End Function   	

   Public Sub DeserializeObject(filename As String)
      ' Create an instance of the XmlSerializer Class that
      ' can generate encoded SOAP messages.
      Dim mySerializer As XmlSerializer =  ReturnSOAPSerializer()

      ' Reading the file requires an  XmlTextReader.
      Dim reader As XmlTextReader = _
      New XmlTextReader(filename)
      reader.ReadStartElement("wrapper")

      ' Deserialize and cast the object.
      Dim myGroup As Group 
      myGroup = _
      CType(mySerializer.Deserialize(reader), Group)
      reader.ReadEndElement()
      reader.Close()

   End Sub
   
   private Function ReturnSOAPSerializer() As XmlSerializer 
      ' Create an instance of the XmlSerializer Class.
      Dim myMapping As XmlTypeMapping = _
      (New SoapReflectionImporter().ImportTypeMapping _
      (GetType(Group)))
       return New XmlSerializer(myMapping)
   End Function
End Class