本文整理汇总了VB.NET中Microsoft.Win32.SafeHandles.SafeWaitHandle.SafeWaitHandle构造函数的典型用法代码示例。如果您正苦于以下问题：VB.NET SafeWaitHandle构造函数的具体用法？VB.NET SafeWaitHandle怎么用？VB.NET SafeWaitHandle使用的例子？那么恭喜您, 这里精选的构造函数代码示例或许可以为您提供帮助。您也可以进一步了解该构造函数所在类Microsoft.Win32.SafeHandles.SafeWaitHandle的用法示例。
在下文中一共展示了SafeWaitHandle构造函数的1个代码示例，这些例子默认根据受欢迎程度排序。您可以为喜欢或者感觉有用的代码点赞，您的评价将有助于系统推荐出更棒的VB.NET代码示例。
示例1: SafeHandlesExample
' 导入命名空间
Imports Microsoft.Win32.SafeHandles
Imports System.Runtime.InteropServices
Class SafeHandlesExample
Shared Sub Main()
Dim uMutex As New UnmanagedMutex("YourCompanyName_SafeHandlesExample_MUTEX")
Try
uMutex.Create()
Console.WriteLine("Mutex created. Press Enter to release it.")
Console.ReadLine()
Catch e As Exception
Console.WriteLine(e)
Finally
uMutex.Release()
Console.WriteLine("Mutex Released.")
End Try
Console.ReadLine()
End Sub
End Class
Class UnmanagedMutex
' Use interop to call the CreateMutex function.
' For more information about CreateMutex,
' see the unmanaged MSDN reference library.
<DllImport("kernel32.dll", CharSet:=CharSet.Unicode)> _
Shared Function CreateMutex(ByVal lpMutexAttributes As IntPtr, ByVal bInitialOwner As Boolean, ByVal lpName As String) As IntPtr
End Function
' Use interop to call the ReleaseMutex function.
' For more information about ReleaseMutex,
' see the unmanaged MSDN reference library.
<DllImport("kernel32.dll")> _
Public Shared Function ReleaseMutex(ByVal hMutex As SafeWaitHandle) As Boolean
End Function
Private handleValue As SafeWaitHandle = Nothing
Private mutexAttrValue As IntPtr = IntPtr.Zero
Private nameValue As String = Nothing
Public Sub New(ByVal Name As String)
nameValue = Name
End Sub
Public Sub Create()
If nameValue Is Nothing AndAlso nameValue.Length = 0 Then
Throw New ArgumentNullException("nameValue")
End If
Dim ptr As IntPtr = CreateMutex(mutexAttrValue, True, nameValue)
handleValue = New SafeWaitHandle(ptr, True)
' If the handle is invalid,
' get the last Win32 error
' and throw a Win32Exception.
If handleValue.IsInvalid Then
Marshal.ThrowExceptionForHR(Marshal.GetHRForLastWin32Error())
End If
End Sub
Public ReadOnly Property Handle() As SafeWaitHandle
Get
' If the handle is valid,
' return it.
If Not handleValue.IsInvalid Then
Return handleValue
Else
Return Nothing
End If
End Get
End Property
Public ReadOnly Property Name() As String
Get
Return nameValue
End Get
End Property
Public Sub Release()
ReleaseMutex(handleValue)
End Sub
End Class