本文整理匯總了VB.NET中System.Windows.Forms.ToolBarButton.Tag屬性的典型用法代碼示例。如果您正苦於以下問題：VB.NET ToolBarButton.Tag屬性的具體用法？VB.NET ToolBarButton.Tag怎麽用？VB.NET ToolBarButton.Tag使用的例子？那麽, 這裏精選的屬性代碼示例或許可以為您提供幫助。您也可以進一步了解該屬性所在類System.Windows.Forms.ToolBarButton的用法示例。
在下文中一共展示了ToolBarButton.Tag屬性的1個代碼示例，這些例子默認根據受歡迎程度排序。您可以為喜歡或者感覺有用的代碼點讚，您的評價將有助於係統推薦出更棒的VB.NET代碼示例。
示例1: InitializeToolBar
' Declare ToolBar1.
Friend WithEvents ToolBar1 As System.Windows.Forms.ToolBar
' Initialize ToolBar1 with Bold(B), Italic(I), and Underline(U) buttons.
Private Sub InitializeToolBar()
ToolBar1 = New ToolBar
' Set the appearance to Flat.
ToolBar1.Appearance = ToolBarAppearance.Flat
' Set the toolbar to dock at the bottom of the form.
ToolBar1.Dock = DockStyle.Bottom
' Set the toolbar font to 14 points and bold.
ToolBar1.Font = New System.Drawing.Font _
(FontFamily.GenericSansSerif, 14, FontStyle.Bold)
' Declare fontstyle array with the three font styles.
Dim fonts() As FontStyle = New FontStyle() _
{FontStyle.Bold, FontStyle.Italic, FontStyle.Underline}
Dim count As Integer
' Create a button for each value in the array, setting its text to the
' first letter of the style and its button's tag property.
For count = 0 To fonts.Length - 1
Dim fontButton As New ToolBarButton(fonts(count). _
ToString.Substring(0, 1))
fontButton.Style = ToolBarButtonStyle.ToggleButton
fontButton.Tag = fonts(count)
ToolBar1.Buttons.Add(fontButton)
Next
Me.Controls.Add(Me.ToolBar1)
End Sub
' Declare FontStyle object, which defaults to the Regular FontStyle.
Dim style As New FontStyle
Private Sub ToolBar1_ButtonClick(ByVal sender As Object, _
ByVal e As System.Windows.Forms.ToolBarButtonClickEventArgs) _
Handles ToolBar1.ButtonClick
' If a button is pushed, use a bitwise Or combination
' of the style variable and the button tag, to set style to
' the correct FontStyle. Set the button's PartialPush property to
' true for a Windows XP-like appearance.
If (e.Button.Pushed) Then
e.Button.PartialPush = True
style = style Or e.Button.Tag
Else
' If the button was not pushed, use a bitwise XOR
' combination to turn off that style
' and set the PartialPush property to False.
e.Button.PartialPush = False
style = style Xor e.Button.Tag
End If
' Set the font using the existing RichTextBox font and the new
' style.
RichTextBox1.Font = New Font(RichTextBox1.Font, style)
End Sub