VB.NET Type.IsGenericTypeDefinition屬性代碼示例

本文整理匯總了VB.NET中System.Type.IsGenericTypeDefinition屬性的典型用法代碼示例。如果您正苦於以下問題：VB.NET Type.IsGenericTypeDefinition屬性的具體用法？VB.NET Type.IsGenericTypeDefinition怎麽用？VB.NET Type.IsGenericTypeDefinition使用的例子？那麽, 這裏精選的屬性代碼示例或許可以為您提供幫助。您也可以進一步了解該屬性所在類System.Type的用法示例。

在下文中一共展示了Type.IsGenericTypeDefinition屬性的1個代碼示例，這些例子默認根據受歡迎程度排序。您可以為喜歡或者感覺有用的代碼點讚，您的評價將有助於係統推薦出更棒的VB.NET代碼示例。

示例1: Test

' 導入命名空間
Imports System.Reflection
Imports System.Collections.Generic

Public Class Test
    Private Shared Sub DisplayGenericTypeInfo(ByVal t As Type) 
        Console.WriteLine(vbCrLf & t.ToString())
        
        Console.WriteLine(vbTab & "Is this a generic type definition? " _
            & t.IsGenericTypeDefinition)
        
        Console.WriteLine(vbTab & "Is it a generic type? " _
            & t.IsGenericType)
        
        If t.IsGenericType Then
            ' If this is a generic type, display the type arguments.
            '
            Dim typeArguments As Type() = t.GetGenericArguments()
            
            Console.WriteLine(vbTab & "List type arguments (" _
                & typeArguments.Length & "):")
            
            For Each tParam As Type In typeArguments
                ' If this is a type parameter, display its position.
                '
                If tParam.IsGenericParameter Then
                    Console.WriteLine(vbTab & vbTab & tParam.ToString() _
                        & vbTab & "(unassigned - parameter position " _
                        & tParam.GenericParameterPosition & ")")
                Else
                    Console.WriteLine(vbTab & vbTab & tParam.ToString())
                End If
            Next tParam
        End If
    
    End Sub 
    
    
    Public Shared Sub Main() 
        Console.WriteLine(vbCrLf & "--- Display information about a constructed type, its")
        Console.WriteLine("    generic type definition, and an ordinary type.")
        
        ' Create a Dictionary of Test objects, using strings for the
        ' keys.       
        Dim d As New Dictionary(Of String, Test)()

        DisplayGenericTypeInfo(d.GetType())
        DisplayGenericTypeInfo(d.GetType().GetGenericTypeDefinition())
        
        ' Display information for an ordinary type.
        DisplayGenericTypeInfo(GetType(String))
    
    End Sub
End Class

開發者ID:VB.NET開發者，項目名稱:System，代碼行數:54，代碼來源:Type.IsGenericTypeDefinition

輸出：

--- Display information about a constructed type, its
generic type definition, and an ordinary type.

System.Collections.Generic.Dictionary[System.String, Test]
Is this a generic type definition? False
Is it a generic type? True
List type arguments (2):
System.String
Test

System.Collections.Generic.Dictionary[TKey,TValue]
Is this a generic type definition? True
Is it a generic type? True
List type arguments (2):
TKey    (unassigned - parameter position 0)
TValue  (unassigned - parameter position 1)

System.String
Is this a generic type definition? False
Is it a generic type? False

注：本文中的System.Type.IsGenericTypeDefinition屬性示例由純淨天空整理自Github/MSDocs等開源代碼及文檔管理平台，相關代碼片段篩選自各路編程大神貢獻的開源項目，源碼版權歸原作者所有，傳播和使用請參考對應項目的License；未經允許，請勿轉載。