本文整理匯總了VB.NET中System.Data.SqlClient.SqlBulkCopyColumnMapping.DestinationOrdinal屬性的典型用法代碼示例。如果您正苦於以下問題：VB.NET SqlBulkCopyColumnMapping.DestinationOrdinal屬性的具體用法？VB.NET SqlBulkCopyColumnMapping.DestinationOrdinal怎麽用？VB.NET SqlBulkCopyColumnMapping.DestinationOrdinal使用的例子？那麽, 這裏精選的屬性代碼示例或許可以為您提供幫助。您也可以進一步了解該屬性所在類System.Data.SqlClient.SqlBulkCopyColumnMapping的用法示例。
在下文中一共展示了SqlBulkCopyColumnMapping.DestinationOrdinal屬性的1個代碼示例，這些例子默認根據受歡迎程度排序。您可以為喜歡或者感覺有用的代碼點讚，您的評價將有助於係統推薦出更棒的VB.NET代碼示例。
示例1: Module1
' 導入命名空間
Imports System.Data.SqlClient
Module Module1
Sub Main()
Dim connectionString As String = GetConnectionString()
' Open a connection to the AdventureWorks database.
Using sourceConnection As SqlConnection = _
New SqlConnection(connectionString)
sourceConnection.Open()
' Perform an initial count on the destination table.
Dim commandRowCount As New SqlCommand( _
"SELECT COUNT(*) FROM dbo.BulkCopyDemoDifferentColumns;", _
sourceConnection)
Dim countStart As Long = _
System.Convert.ToInt32(commandRowCount.ExecuteScalar())
Console.WriteLine("Starting row count = {0}", countStart)
' Get data from the source table as a SqlDataReader.
Dim commandSourceData As SqlCommand = New SqlCommand( _
"SELECT ProductID, Name, ProductNumber " & _
"FROM Production.Product;", sourceConnection)
Dim reader As SqlDataReader = commandSourceData.ExecuteReader
' Set up the bulk copy object.
Using bulkCopy As SqlBulkCopy = New SqlBulkCopy(connectionString)
bulkCopy.DestinationTableName = _
"dbo.BulkCopyDemoDifferentColumns"
' Set up the column mappings source and destination.
Dim mapID As New SqlBulkCopyColumnMapping()
mapID.SourceOrdinal = 0
mapID.DestinationOrdinal = 0
bulkCopy.ColumnMappings.Add(mapID)
Dim mapName As New SqlBulkCopyColumnMapping()
mapName.SourceOrdinal = 1
mapName.DestinationOrdinal = 2
bulkCopy.ColumnMappings.Add(mapName)
Dim mapNumber As New SqlBulkCopyColumnMapping()
mapNumber.SourceOrdinal = 2
mapNumber.DestinationOrdinal = 1
bulkCopy.ColumnMappings.Add(mapNumber)
' Write from the source to the destination.
Try
bulkCopy.WriteToServer(reader)
Catch ex As Exception
Console.WriteLine(ex.Message)
Finally
' Close the SqlDataReader. The SqlBulkCopy
' object is automatically closed at the end
' of the Using block.
reader.Close()
End Try
End Using
' Perform a final count on the destination table
' to see how many rows were added.
Dim countEnd As Long = _
System.Convert.ToInt32(commandRowCount.ExecuteScalar())
Console.WriteLine("Ending row count = {0}", countEnd)
Console.WriteLine("{0} rows were added.", countEnd - countStart)
Console.WriteLine("Press Enter to finish.")
Console.ReadLine()
End Using
End Sub
Private Function GetConnectionString() As String
' To avoid storing the sourceConnection string in your code,
' you can retrieve it from a configuration file.
Return "Data Source=(local);" & _
"Integrated Security=true;" & _
"Initial Catalog=AdventureWorks;"
End Function
End Module