VB.NET Storyboard.Begin方法代碼示例

' 導入命名空間
Imports System.Windows
Imports System.Windows.Controls
Imports System.Windows.Shapes
Imports System.Windows.Media
Imports System.Windows.Media.Animation

Namespace SDKSample

    Public Class ControllableStoryboardExample
        Inherits Page
        Private myStoryboard As Storyboard

        Public Sub New()

            ' Create a name scope for the page.

            NameScope.SetNameScope(Me, New NameScope())

            Me.WindowTitle = "Controllable Storyboard Example"
            Dim myStackPanel As New StackPanel()
            myStackPanel.Margin = New Thickness(10)

            ' Create a rectangle.
            Dim myRectangle As New Rectangle()
            myRectangle.Name = "myRectangle"

            ' Assign the rectangle a name by 
            ' registering it with the page, so that
            ' it can be targeted by storyboard
            ' animations.
            Me.RegisterName(myRectangle.Name, myRectangle)
            myRectangle.Width = 100
            myRectangle.Height = 100
            myRectangle.Fill = Brushes.Blue
            myStackPanel.Children.Add(myRectangle)

            '
            ' Create an animation and a storyboard to animate the
            ' rectangle.
            '
            Dim myDoubleAnimation As New DoubleAnimation()
            myDoubleAnimation.From = 1.0
            myDoubleAnimation.To = 0.0
            myDoubleAnimation.Duration = New Duration(TimeSpan.FromMilliseconds(5000))
            myDoubleAnimation.AutoReverse = True

            ' Create the storyboard.
            myStoryboard = New Storyboard()
            myStoryboard.Children.Add(myDoubleAnimation)
            Storyboard.SetTargetName(myDoubleAnimation, myRectangle.Name)
            Storyboard.SetTargetProperty(myDoubleAnimation, New PropertyPath(Rectangle.OpacityProperty))

            '
            ' Create some buttons to control the storyboard
            ' and a panel to contain them.
            '
            Dim buttonPanel As New StackPanel()
            buttonPanel.Orientation = Orientation.Horizontal
            Dim beginButton As New Button()
            beginButton.Content = "Begin"
            AddHandler beginButton.Click, AddressOf beginButton_Clicked
            buttonPanel.Children.Add(beginButton)
            Dim pauseButton As New Button()
            pauseButton.Content = "Pause"
            AddHandler pauseButton.Click, AddressOf pauseButton_Clicked
            buttonPanel.Children.Add(pauseButton)
            Dim resumeButton As New Button()
            resumeButton.Content = "Resume"
            AddHandler resumeButton.Click, AddressOf resumeButton_Clicked
            buttonPanel.Children.Add(resumeButton)
            Dim skipToFillButton As New Button()
            skipToFillButton.Content = "Skip to Fill"
            AddHandler skipToFillButton.Click, AddressOf skipToFillButton_Clicked
            buttonPanel.Children.Add(skipToFillButton)
            Dim setSpeedRatioButton As New Button()
            setSpeedRatioButton.Content = "Triple Speed"
            AddHandler setSpeedRatioButton.Click, AddressOf setSpeedRatioButton_Clicked
            buttonPanel.Children.Add(setSpeedRatioButton)
            Dim stopButton As New Button()
            stopButton.Content = "Stop"
            AddHandler stopButton.Click, AddressOf stopButton_Clicked
            buttonPanel.Children.Add(stopButton)
            myStackPanel.Children.Add(buttonPanel)
            Me.Content = myStackPanel


        End Sub

        ' Begins the storyboard.
        Private Sub beginButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
            ' Specifying "true" as the second Begin parameter
            ' makes this storyboard controllable.
            myStoryboard.Begin(Me, True)

        End Sub

        ' Pauses the storyboard.
        Private Sub pauseButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
            myStoryboard.Pause(Me)

        End Sub

        ' Resumes the storyboard.
        Private Sub resumeButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
            myStoryboard.Resume(Me)

        End Sub

        ' Advances the storyboard to its fill period.
        Private Sub skipToFillButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
            myStoryboard.SkipToFill(Me)

        End Sub

        ' Updates the storyboard's speed.
        Private Sub setSpeedRatioButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
            ' Makes the storyboard progress three times as fast as normal.
            myStoryboard.SetSpeedRatio(Me, 3)

        End Sub

        ' Stops the storyboard.
        Private Sub stopButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
            myStoryboard.Stop(Me)

        End Sub

    End Class

End Namespace

'
'
'   This sample animates the position of an ellipse when 
'   the user clicks within the main border. If the user
'   left-clicks, the SnapshotAndReplace HandoffBehavior
'   is used when applying the animations. If the user
'   right-clicks, the Compose HandoffBehavior is used
'   instead.
'
'


Imports System.Windows
Imports System.Windows.Navigation
Imports System.Windows.Media
Imports System.Windows.Media.Animation
Imports System.Windows.Shapes
Imports System.Windows.Controls
Imports System.Windows.Input

Namespace Microsoft.Samples.Animation.AnimatingWithStoryboards

    ' Create the demonstration.
    Public Class FrameworkElementStoryboardHandoffBehaviorExample
        Inherits Page


        Private containerBorder As Border
        Private interactiveEllipse As Ellipse
        Private theStoryboard As Storyboard
        Private xAnimation As DoubleAnimation
        Private yAnimation As DoubleAnimation

        Public Sub New()

            WindowTitle = "Interactive Animation Example"

            ' Create a name scope for the page.
            NameScope.SetNameScope(Me, New NameScope())

            Dim myPanel As New DockPanel()
            myPanel.Margin = New Thickness(20.0)

            containerBorder = New Border()
            containerBorder.Background = Brushes.White
            containerBorder.BorderBrush = Brushes.Black
            containerBorder.BorderThickness = New Thickness(2.0)
            containerBorder.VerticalAlignment = VerticalAlignment.Stretch

            interactiveEllipse = New Ellipse()
            With interactiveEllipse
                .Fill = Brushes.Lime
                .Stroke = Brushes.Black
                .StrokeThickness = 2.0
                .Width = 25
                .Height = 25
                .HorizontalAlignment = HorizontalAlignment.Left
                .VerticalAlignment = VerticalAlignment.Top
            End With

            Dim interactiveTranslateTransform As New TranslateTransform()
            Me.RegisterName("InteractiveTranslateTransform", interactiveTranslateTransform)

            interactiveEllipse.RenderTransform = interactiveTranslateTransform

            xAnimation = New DoubleAnimation()
            xAnimation.Duration = TimeSpan.FromSeconds(4)
            yAnimation = xAnimation.Clone()
            Storyboard.SetTargetName(xAnimation, "InteractiveTranslateTransform")
            Storyboard.SetTargetProperty(xAnimation, New PropertyPath(TranslateTransform.XProperty))
            Storyboard.SetTargetName(yAnimation, "InteractiveTranslateTransform")
            Storyboard.SetTargetProperty(yAnimation, New PropertyPath(TranslateTransform.YProperty))

            theStoryboard = New Storyboard()
            theStoryboard.Children.Add(xAnimation)
            theStoryboard.Children.Add(yAnimation)


            AddHandler containerBorder.MouseLeftButtonDown, AddressOf border_mouseLeftButtonDown
            AddHandler containerBorder.MouseRightButtonDown, AddressOf border_mouseRightButtonDown

            containerBorder.Child = interactiveEllipse
            myPanel.Children.Add(containerBorder)
            Me.Content = myPanel
        End Sub


        ' When the user left-clicks, use the 
        ' SnapshotAndReplace HandoffBehavior when applying the animation.        
        Private Sub border_mouseLeftButtonDown(ByVal sender As Object, ByVal e As MouseButtonEventArgs)

            Dim clickPoint As Point = Mouse.GetPosition(containerBorder)

            ' Set the target point so the center of the ellipse
            ' ends up at the clicked point.
            Dim targetPoint As New Point()
            targetPoint.X = clickPoint.X - interactiveEllipse.Width / 2
            targetPoint.Y = clickPoint.Y - interactiveEllipse.Height / 2

            ' Animate to the target point.
            xAnimation.To = targetPoint.X
            yAnimation.To = targetPoint.Y
            theStoryboard.Begin(Me, HandoffBehavior.SnapshotAndReplace)


            ' Change the color of the ellipse.
            interactiveEllipse.Fill = Brushes.Lime

        End Sub

        ' When the user right-clicks, use the 
        ' Compose HandoffBehavior when applying the animation.
        Private Sub border_mouseRightButtonDown(ByVal sender As Object, ByVal e As MouseButtonEventArgs)

            ' Find the point where the use clicked.
            Dim clickPoint As Point = Mouse.GetPosition(containerBorder)

            ' Set the target point so the center of the ellipse
            ' ends up at the clicked point.
            Dim targetPoint As New Point()
            targetPoint.X = clickPoint.X - interactiveEllipse.Width / 2
            targetPoint.Y = clickPoint.Y - interactiveEllipse.Height / 2

            ' Animate to the target point.
            xAnimation.To = targetPoint.X
            yAnimation.To = targetPoint.Y
            theStoryboard.Begin(Me, HandoffBehavior.Compose)

            ' Change the color of the ellipse.
            interactiveEllipse.Fill = Brushes.Orange


        End Sub

    End Class

End Namespace

'
'    This example shows how to control
'    a storyboard after it has started.
'
'


Imports System.Windows
Imports System.Windows.Controls
Imports System.Windows.Media
Imports System.Windows.Shapes
Imports System.Windows.Media.Animation
Imports System.Windows.Documents


Namespace Microsoft.Samples.Animation.AnimatingWithStoryboards
    Public Class FrameworkContentElementControlStoryboardExample
        Inherits FlowDocument

        Private myStoryboard As Storyboard

        Public Sub New()

            ' Create a name scope for the document.
            NameScope.SetNameScope(Me, New NameScope())
            Me.Background = Brushes.White

            ' Create a run of text.
            Dim theText As New Run("Lorem ipsum dolor sit amet, consectetuer adipiscing elit." & "Ut non lacus. Nullam a ligula id leo adipiscing ornare." & " Duis mattis. ")

            ' Create a TextEffect
            Dim animatedSpecialEffect As New TextEffect()
            animatedSpecialEffect.Foreground = Brushes.OrangeRed
            animatedSpecialEffect.PositionStart = 0
            animatedSpecialEffect.PositionCount = 0

            ' Assign the TextEffect a name by 
            ' registering it with the page, so that
            ' it can be targeted by storyboard
            ' animations            
            Me.RegisterName("animatedSpecialEffect", animatedSpecialEffect)

            ' Apply the text effect to the run.
            theText.TextEffects = New TextEffectCollection()
            theText.TextEffects.Add(animatedSpecialEffect)

            ' Create a paragraph to contain the run.
            Dim animatedParagraph As New Paragraph(theText)
            animatedParagraph.Background = Brushes.LightGray
            animatedParagraph.Padding = New Thickness(20)

            Me.Blocks.Add(animatedParagraph)
            Dim controlsContainer As New BlockUIContainer()

            '
            ' Create an animation and a storyboard to animate the
            ' text effect.
            '
            Dim countAnimation As New Int32Animation(0, 127, TimeSpan.FromSeconds(10))
            Storyboard.SetTargetName(countAnimation, "animatedSpecialEffect")
            Storyboard.SetTargetProperty(countAnimation, New PropertyPath(TextEffect.PositionCountProperty))
            myStoryboard = New Storyboard()
            myStoryboard.Children.Add(countAnimation)

            '
            ' Create some buttons to control the storyboard
            ' and a panel to contain them.
            '
            Dim buttonPanel As New StackPanel()
            buttonPanel.Orientation = Orientation.Vertical
            Dim beginButton As New Button()
            beginButton.Content = "Begin"
            AddHandler beginButton.Click, AddressOf beginButton_Clicked
            buttonPanel.Children.Add(beginButton)
            Dim pauseButton As New Button()
            pauseButton.Content = "Pause"
            AddHandler pauseButton.Click, AddressOf pauseButton_Clicked
            buttonPanel.Children.Add(pauseButton)
            Dim resumeButton As New Button()
            resumeButton.Content = "Resume"
            AddHandler resumeButton.Click, AddressOf resumeButton_Clicked
            buttonPanel.Children.Add(resumeButton)
            Dim skipToFillButton As New Button()
            skipToFillButton.Content = "Skip to Fill"
            AddHandler skipToFillButton.Click, AddressOf skipToFillButton_Clicked
            buttonPanel.Children.Add(skipToFillButton)
            Dim setSpeedRatioButton As New Button()
            setSpeedRatioButton.Content = "Triple Speed"
            AddHandler setSpeedRatioButton.Click, AddressOf setSpeedRatioButton_Clicked
            buttonPanel.Children.Add(setSpeedRatioButton)
            Dim stopButton As New Button()
            stopButton.Content = "Stop"
            AddHandler stopButton.Click, AddressOf stopButton_Clicked
            buttonPanel.Children.Add(stopButton)
            Dim removeButton As New Button()
            removeButton.Content = "Remove"
            AddHandler removeButton.Click, AddressOf removeButton_Clicked
            buttonPanel.Children.Add(removeButton)

            controlsContainer.Child = buttonPanel
            Me.Blocks.Add(controlsContainer)

        End Sub

        ' Begins the storyboard.
        Private Sub beginButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
            ' Specifying "true" as the second Begin parameter
            ' makes this storyboard controllable.
            myStoryboard.Begin(Me, True)

        End Sub

        ' Pauses the storyboard.
        Private Sub pauseButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
             myStoryboard.Pause(Me)

        End Sub

        ' Resumes the storyboard.
        Private Sub resumeButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
             myStoryboard.Resume(Me)

        End Sub

        ' Advances the storyboard to its fill period.
        Private Sub skipToFillButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
             myStoryboard.SkipToFill(Me)

        End Sub

        ' Updates the storyboard's speed.
        Private Sub setSpeedRatioButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
            ' Makes the storyboard progress three times as fast as normal.
            myStoryboard.SetSpeedRatio(Me, 3)

        End Sub

        ' Stops the storyboard.
        Private Sub stopButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
             myStoryboard.Stop(Me)

        End Sub

        ' Removes the storyboard.
        Private Sub removeButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)
             myStoryboard.Remove(Me)

        End Sub

    End Class
End Namespace

'
'    This example shows how to animate
'    a FrameworkContentElement with a storyboard.
'
'


Imports System.Windows
Imports System.Windows.Controls
Imports System.Windows.Media
Imports System.Windows.Shapes
Imports System.Windows.Media.Animation
Imports System.Windows.Documents
Imports System.Windows.Input


Namespace Microsoft.Samples.Animation.AnimatingWithStoryboards
    Public Class FrameworkContentElementStoryboardWithHandoffBehaviorExample
        Inherits FlowDocument

        Private myStoryboard As Storyboard
        Private xAnimation As DoubleAnimation
        Private yAnimation As DoubleAnimation

        Public Sub New()

            ' Create a name scope for the document.
            NameScope.SetNameScope(Me, New NameScope())
            Me.Background = Brushes.Orange

            ' Create a run of text.
            Dim theText As New Run("Lorem ipsum dolor sit amet, consectetuer adipiscing elit.")

            ' Create a TextEffect
            Dim animatedSpecialEffect As New TextEffect()
            animatedSpecialEffect.Foreground = Brushes.OrangeRed
            animatedSpecialEffect.PositionStart = 0
            animatedSpecialEffect.PositionCount = 20

            Dim animatedTransform As New TranslateTransform()

            ' Assign the transform a name by 
            ' registering it with the page, so that
            ' it can be targeted by storyboard
            ' animations.      
            Me.RegisterName("animatedTransform", animatedTransform)
            animatedSpecialEffect.Transform = animatedTransform


            ' Apply the text effect to the run.
            theText.TextEffects = New TextEffectCollection()
            theText.TextEffects.Add(animatedSpecialEffect)


            ' Create a paragraph to contain the run.
            Dim animatedParagraph As New Paragraph(theText)
            animatedParagraph.Background = Brushes.LightGray

            Me.Blocks.Add(animatedParagraph)

            '
            ' Create a storyboard to animate the
            ' text effect's transform.
            '
            myStoryboard = New Storyboard()

            xAnimation = New DoubleAnimation()
            xAnimation.Duration = TimeSpan.FromSeconds(5)
            Storyboard.SetTargetName(xAnimation, "animatedTransform")
            Storyboard.SetTargetProperty(xAnimation, New PropertyPath(TranslateTransform.XProperty))
            myStoryboard.Children.Add(xAnimation)

            yAnimation = New DoubleAnimation()
            yAnimation.Duration = TimeSpan.FromSeconds(5)
            Storyboard.SetTargetName(yAnimation, "animatedTransform")
            Storyboard.SetTargetProperty(yAnimation, New PropertyPath(TranslateTransform.YProperty))
            myStoryboard.Children.Add(yAnimation)

            AddHandler MouseLeftButtonDown, AddressOf document_mouseLeftButtonDown
            AddHandler MouseRightButtonDown, AddressOf document_mouseRightButtonDown

        End Sub



        ' When the user left-clicks, use the 
        ' SnapshotAndReplace HandoffBehavior when applying the animation.        
        Private Sub document_mouseLeftButtonDown(ByVal sender As Object, ByVal e As MouseButtonEventArgs)

            Dim clickPoint As Point = Mouse.GetPosition(Me)


            ' Animate to the target point.
            xAnimation.To = clickPoint.X
            yAnimation.To = clickPoint.Y

            Try
                myStoryboard.Begin(Me, HandoffBehavior.SnapshotAndReplace)

            Catch ex As Exception
                MessageBox.Show(ex.ToString())
            End Try
        End Sub

        ' When the user right-clicks, use the 
        ' Compose HandoffBehavior when applying the animation.
        Private Sub document_mouseRightButtonDown(ByVal sender As Object, ByVal e As MouseButtonEventArgs)


            Dim clickPoint As Point = Mouse.GetPosition(Me)

            ' Animate to the target point.
            xAnimation.To = clickPoint.X
            yAnimation.To = clickPoint.Y
            myStoryboard.Begin(Me, HandoffBehavior.Compose)


        End Sub





    End Class
End Namespace

'
'    This example shows how to animate
'    a FrameworkContentElement with a storyboard.
'
'


Imports System.Windows
Imports System.Windows.Controls
Imports System.Windows.Media
Imports System.Windows.Shapes
Imports System.Windows.Media.Animation
Imports System.Windows.Documents


Namespace Microsoft.Samples.Animation.AnimatingWithStoryboards
    Public Class FrameworkContentElementStoryboardExample
        Inherits FlowDocument

        Private myStoryboard As Storyboard

        Public Sub New()

            ' Create a name scope for the document.
            NameScope.SetNameScope(Me, New NameScope())
            Me.Background = Brushes.White

            ' Create a run of text.
            Dim theText As New Run("Lorem ipsum dolor sit amet, consectetuer adipiscing elit." & "Ut non lacus. Nullam a ligula id leo adipiscing ornare." & " Duis mattis. ")

            ' Create a TextEffect
            Dim animatedSpecialEffect As New TextEffect()
            animatedSpecialEffect.Foreground = Brushes.OrangeRed
            animatedSpecialEffect.PositionStart = 0
            animatedSpecialEffect.PositionCount = 0

            ' Assign the TextEffect a name by 
            ' registering it with the page, so that
            ' it can be targeted by storyboard
            ' animations            
            Me.RegisterName("animatedSpecialEffect", animatedSpecialEffect)

            ' Apply the text effect to the run.
            theText.TextEffects = New TextEffectCollection()
            theText.TextEffects.Add(animatedSpecialEffect)

            ' Create a paragraph to contain the run.
            Dim animatedParagraph As New Paragraph(theText)
            animatedParagraph.Background = Brushes.LightGray
            animatedParagraph.Padding = New Thickness(20)

            Me.Blocks.Add(animatedParagraph)
            Dim controlsContainer As New BlockUIContainer()

            '
            ' Create an animation and a storyboard to animate the
            ' text effect.
            '
            Dim countAnimation As New Int32Animation(0, 127, TimeSpan.FromSeconds(10))
            Storyboard.SetTargetName(countAnimation, "animatedSpecialEffect")
            Storyboard.SetTargetProperty(countAnimation, New PropertyPath(TextEffect.PositionCountProperty))
            myStoryboard = New Storyboard()
            myStoryboard.Children.Add(countAnimation)

            '
            ' Create a button to start the storyboard.
            '
            Dim beginButton As New Button()
            beginButton.Content = "Begin"
            AddHandler beginButton.Click, AddressOf beginButton_Clicked

            controlsContainer.Child = beginButton
            Me.Blocks.Add(controlsContainer)

        End Sub

        ' Begins the storyboard.
        Private Sub beginButton_Clicked(ByVal sender As Object, ByVal args As RoutedEventArgs)

            myStoryboard.Begin(Me)
        End Sub



    End Class
End Namespace