VB.NET UInt64.TryParse方法代碼示例

本文整理匯總了VB.NET中System.UInt64.TryParse方法的典型用法代碼示例。如果您正苦於以下問題：VB.NET UInt64.TryParse方法的具體用法？VB.NET UInt64.TryParse怎麽用？VB.NET UInt64.TryParse使用的例子？那麽, 這裏精選的方法代碼示例或許可以為您提供幫助。

在下文中一共展示了UInt64.TryParse方法的2個代碼示例，這些例子默認根據受歡迎程度排序。您可以為喜歡或者感覺有用的代碼點讚，您的評價將有助於係統推薦出更棒的VB.NET代碼示例。

示例1: numericStrings

Dim numericStrings() As String = {"1293.8", "+1671.7", "28347.", _
                                  "   33113684  ", "(0)", "-0", "+1293617", _
                                  "18-", "119870", "31,024", "  3127094 ", _ 
                                  "0070000" }
Dim number As ULong
For Each numericString As String In numericStrings
   If UInt64.TryParse(numericString, number) Then
      Console.WriteLine("Converted '{0}' to {1}.", numericString, number)
   Else
      Console.WriteLine("Cannot convert '{0}' to a UInt64.", numericString)
   End If      
Next

開發者ID:VB.NET開發者，項目名稱:System，代碼行數:12，代碼來源:UInt64.TryParse

輸出：

Cannot convert '1293.8' to a UInt64.
Cannot convert '+1671.7' to a UInt64.
Cannot convert '28347.' to a UInt64.
Converted '   33113684  ' to 33113684.
Cannot convert '(0)' to a UInt64.
Converted '-0' to 0.
Converted '+1293617' to 1293617.
Cannot convert '18-' to a UInt64.
Converted '119870' to 119870.
Cannot convert '31,024' to a UInt64.
Converted '  3127094 ' to 3127094.
Converted '0070000' to 70000.

示例2: Example

' 導入命名空間
Imports System.Globalization

Module Example
   Public Sub Main()
      Dim numericString As String
      Dim styles As NumberStyles
      
      numericString = "2106034"
      styles = NumberStyles.Integer
      CallTryParse(numericString, styles)
      
      numericString = "-10603"
      styles = NumberStyles.None
      CallTryParse(numericString, styles)
      
      numericString = "29103674.00"
      styles = NumberStyles.Integer Or NumberStyles.AllowDecimalPoint
      CallTryParse(numericString, styles)
      
      numericString = "10345.72"
      styles = NumberStyles.Integer Or NumberStyles.AllowDecimalPoint
      CallTryParse(numericString, styles)

      numericString = "41792210E-01"
      styles = NumberStyles.Integer Or NumberStyles.AllowExponent
      CallTryParse(numericString, styles) 
      
      numericString = "9112E-01"
      CallTryParse(numericString, styles)
          
      numericString = "312E01"
      CallTryParse(numericString, styles) 
      
      numericString = "FFC86DA1"
      CallTryParse(numericString, NumberStyles.HexNumber)
      
      numericString = "0x8F8C"
      CallTryParse(numericString, NumberStyles.HexNumber)
   End Sub
   
   Private Sub CallTryParse(stringToConvert As String, styles AS NumberStyles)
      Dim number As ULong
      Dim result As Boolean = UInt64.TryParse(stringToConvert, styles, _
                                              CultureInfo.InvariantCulture, number)
      If result Then
         Console.WriteLine("Converted '{0}' to {1}.", stringToConvert, number)
      Else
         Console.WriteLine("Attempted conversion of '{0}' failed.", _
                           Convert.ToString(stringToConvert))
      End If                                                                           
   End Sub
End Module

開發者ID:VB.NET開發者，項目名稱:System，代碼行數:53，代碼來源:UInt64.TryParse

輸出：

Converted '2106034' to 2106034.
Attempted conversion of '-10603' failed.
Converted '29103674.00' to 29103674.
Attempted conversion of '10345.72' failed.
Converted '41792210E-01' to 4179221.
Attempted conversion of '9112E-01' failed.
Converted '312E01' to 3120.
Converted 'FFC86DA1' to 4291325345.
Attempted conversion of '0x8F8C' failed.

注：本文中的System.UInt64.TryParse方法示例由純淨天空整理自Github/MSDocs等開源代碼及文檔管理平台，相關代碼片段篩選自各路編程大神貢獻的開源項目，源碼版權歸原作者所有，傳播和使用請參考對應項目的License；未經允許，請勿轉載。