VB.NET PackageStore.GetPackage方法代碼示例

' --------------------------- OpenDocument ---------------------------
''' <summary>
'''   Loads and displays a given XPS document file.</summary>
''' <param name="filename">
'''   The path and file name of the XPS
'''   document to load and display.</param>
''' <returns>
'''   true if the document loads successfully; otherwise false.</returns>
Public Function OpenDocument(ByVal xpsFile As String) As Boolean
    ' Check to see if the document is encrypted.
    ' If encrypted, use OpenEncryptedDocument().
    If EncryptedPackageEnvelope.IsEncryptedPackageEnvelope(xpsFile) Then
        Return OpenEncryptedDocument(xpsFile)
    End If

    ' Document is not encrypted, open normally.
    ShowStatus("Opening '" & Filename(xpsFile) & "'")

    _packageUri = New Uri(xpsFile, UriKind.Absolute)
    Try
        _xpsDocument = New XpsDocument(xpsFile, FileAccess.Read)
    Catch ex As System.IO.FileFormatException
        MessageBox.Show(xpsFile & vbLf & vbLf & "The file " & "is not a valid XPS document." & vbLf & vbLf & "Exception: " & ex.Message & vbLf & vbLf & ex.GetType().ToString() & vbLf & vbLf & ex.StackTrace, "Invalid File Format", MessageBoxButton.OK, MessageBoxImage.Error)
        Return False
    End Try


    ' Get the document's PackageStore into which
    ' new user annotations will be added and saved.
    _xpsPackage = PackageStore.GetPackage(_packageUri)
    If (_xpsPackage Is Nothing) OrElse (_xpsDocument Is Nothing) Then
        MessageBox.Show("Unable to get Package from file.")
        Return False
    End If

    ' Get the FixedDocumentSequence from the open document.
    Dim fds As FixedDocumentSequence = _xpsDocument.GetFixedDocumentSequence()
    If fds Is Nothing Then
        MessageBox.Show(xpsFile & vbLf & vbLf & "The document package within " & "the specified file does not contain a " & "FixedDocumentSequence.", "Package Error")
        Return False
    End If

    ' Load the FixedDocumentSequence to the DocumentViewer control.
    DocViewerProperty.Document = fds

    ' Enable document menu controls.
    menuFileClose.IsEnabled = True
    menuFilePrint.IsEnabled = True
    menuViewIncreaseZoom.IsEnabled = True
    menuViewDecreaseZoom.IsEnabled = True

    ' Give the DocumentViewer focus.
    docViewer.Focus()

    Me.Title = "RightsManagedPackageViewer SDK Sample - " & Filename(xpsFile)
    Return True
End Function ' end:OpenDocument()