VB.NET IEditableObject接口代碼示例

本文整理匯總了VB.NET中System.ComponentModel.IEditableObject接口的典型用法代碼示例。如果您正苦於以下問題：VB.NET IEditableObject接口的具體用法？VB.NET IEditableObject怎麽用？VB.NET IEditableObject使用的例子？那麽, 這裏精選的接口代碼示例或許可以為您提供幫助。

在下文中一共展示了IEditableObject接口的1個代碼示例，這些例子默認根據受歡迎程度排序。您可以為喜歡或者感覺有用的代碼點讚，您的評價將有助於係統推薦出更棒的VB.NET代碼示例。

示例1: Customer

Public Class Customer
    Implements IEditableObject

    Structure CustomerData
        Friend id As String
        Friend firstName As String
        Friend lastName As String
    End Structure 

    Public parent As CustomersList
    Private custData As CustomerData
    Private backupData As CustomerData
    Private inTxn As Boolean = False


    ' Implements IEditableObject
    Sub BeginEdit() Implements IEditableObject.BeginEdit
        Console.WriteLine("Start BeginEdit")
        If Not inTxn Then
            Me.backupData = custData
            inTxn = True
            Console.WriteLine(("BeginEdit - " + Me.backupData.lastName))
        End If
        Console.WriteLine("End BeginEdit")
    End Sub 


    Sub CancelEdit() Implements IEditableObject.CancelEdit
        Console.WriteLine("Start CancelEdit")
        If inTxn Then
            Me.custData = backupData
            inTxn = False
            Console.WriteLine(("CancelEdit - " + Me.custData.lastName))
        End If
        Console.WriteLine("End CancelEdit")
    End Sub 


    Sub EndEdit() Implements IEditableObject.EndEdit
        Console.WriteLine(("Start EndEdit" + Me.custData.id + Me.custData.lastName))
        If inTxn Then
            backupData = New CustomerData()
            inTxn = False
            Console.WriteLine(("Done EndEdit - " + Me.custData.id + Me.custData.lastName))
        End If
        Console.WriteLine("End EndEdit")
    End Sub 


    Public Sub New(ByVal ID As String)
        Me.custData = New CustomerData()
        Me.custData.id = ID
        Me.custData.firstName = ""
        Me.custData.lastName = ""
    End Sub 


    Public ReadOnly Property ID() As String
        Get
            Return Me.custData.id
        End Get
    End Property


    Public Property FirstName() As String
        Get
            Return Me.custData.firstName
        End Get
        Set(ByVal Value As String)
            Me.custData.firstName = Value
            Me.OnCustomerChanged()
        End Set
    End Property


    Public Property LastName() As String
        Get
            Return Me.custData.lastName
        End Get
        Set(ByVal Value As String)
            Me.custData.lastName = Value
            Me.OnCustomerChanged()
        End Set
    End Property


    Friend Property Parents() As CustomersList
        Get
            Return Parent
        End Get
        Set(ByVal Value As CustomersList)
            parent = Value
        End Set
    End Property


    Private Sub OnCustomerChanged()
        If Not inTxn And (Parent IsNot Nothing) Then
            Parent.CustomerChanged(Me)
        End If
    End Sub 

    
    Public Overrides Function ToString() As String
        Dim sb As New StringWriter()
        sb.Write(Me.FirstName)
        sb.Write(" ")
        sb.Write(Me.LastName)
        Return sb.ToString()
    End Function 
End Class

開發者ID:VB.NET開發者，項目名稱:System.ComponentModel，代碼行數:111，代碼來源:IEditableObject

注：本文中的System.ComponentModel.IEditableObject接口示例由純淨天空整理自Github/MSDocs等開源代碼及文檔管理平台，相關代碼片段篩選自各路編程大神貢獻的開源項目，源碼版權歸原作者所有，傳播和使用請參考對應項目的License；未經允許，請勿轉載。