本文整理匯總了VB.NET中System.Xml.Schema.XmlSchemaMinLengthFacet類的典型用法代碼示例。如果您正苦於以下問題：VB.NET XmlSchemaMinLengthFacet類的具體用法？VB.NET XmlSchemaMinLengthFacet怎麽用？VB.NET XmlSchemaMinLengthFacet使用的例子？那麽, 這裏精選的類代碼示例或許可以為您提供幫助。
在下文中一共展示了XmlSchemaMinLengthFacet類的1個代碼示例，這些例子默認根據受歡迎程度排序。您可以為喜歡或者感覺有用的代碼點讚，您的評價將有助於係統推薦出更棒的VB.NET代碼示例。
示例1: XMLSchemaExamples
' 導入命名空間
Imports System.Xml
Imports System.Xml.Schema
Class XMLSchemaExamples
Public Shared Sub Main()
Dim schema As New XmlSchema()
' <xs:simpleType name="ZipCodeType">
Dim ZipCodeType As New XmlSchemaSimpleType()
ZipCodeType.Name = "ZipCodeType"
' <xs:restriction base="xs:string">
Dim restriction As New XmlSchemaSimpleTypeRestriction()
restriction.BaseTypeName = New XmlQualifiedName("string", "http://www.w3.org/2001/XMLSchema")
' <xs:minLength value="5"/>
Dim minLength As New XmlSchemaMinLengthFacet()
minLength.Value = "5"
restriction.Facets.Add(minLength)
ZipCodeType.Content = restriction
schema.Items.Add(ZipCodeType)
' <xs:element name="Address">
Dim element As New XmlSchemaElement()
element.Name = "Address"
' <xs:complexType>
Dim complexType As New XmlSchemaComplexType()
' <xs:attribute name="ZipCode" type="ZipCodeType"/>
Dim ZipCodeAttribute As New XmlSchemaAttribute()
ZipCodeAttribute.Name = "ZipCode"
ZipCodeAttribute.SchemaTypeName = New XmlQualifiedName("ZipCodeType", "")
complexType.Attributes.Add(ZipCodeAttribute)
element.SchemaType = complexType
schema.Items.Add(element)
Dim schemaSet As New XmlSchemaSet()
AddHandler schemaSet.ValidationEventHandler, AddressOf ValidationCallbackOne
schemaSet.Add(schema)
schemaSet.Compile()
Dim compiledSchema As XmlSchema = Nothing
For Each schema1 As XmlSchema In schemaSet.Schemas()
compiledSchema = schema1
Next
Dim nsmgr As New XmlNamespaceManager(New NameTable())
nsmgr.AddNamespace("xs", "http://www.w3.org/2001/XMLSchema")
compiledSchema.Write(Console.Out, nsmgr)
End Sub
Public Shared Sub ValidationCallbackOne(ByVal sender As Object, ByVal args As ValidationEventArgs)
Console.WriteLine(args.Message)
End Sub
End Class