Elixir Access用法及代碼示例

基於鍵的數據結構訪問。

Access 模塊定義了一種行為，用於通過 data[key] 語法動態訪問數據結構中任何類型的鍵。

Access 支持開箱即用的關鍵字列表 ( Keyword ) 和Map ( Map )。關鍵字僅支持原子鍵，映射的鍵可以是任何類型。如果 key 不存在，兩者都返回nil：

iex> keywords = [a: 1, b: 2]
iex> keywords[:a]
1
iex> keywords[:c]
nil

iex> map = %{a: 1, b: 2}
iex> map[:a]
1

iex> star_ratings = %{1.0 => "★", 1.5 => "★☆", 2.0 => "★★"}
iex> star_ratings[1.5]
"★☆"

這種語法非常方便，因為它可以任意嵌套：

iex> keywords = [a: 1, b: 2]
iex> keywords[:c][:unknown]
nil

這是有效的，因為訪問 nil 值上的任何內容都會返回 nil 本身：

iex> nil[:a]
nil

訪問語法也可以與 Kernel.put_in/2 、 Kernel.update_in/2 和 Kernel.get_and_update_in/2 宏一起使用，以允許在嵌套數據結構中設置值：

iex> users = %{"john" => %{age: 27}, "meg" => %{age: 23}}
iex> put_in(users["john"][:age], 28)
%{"john" => %{age: 28}, "meg" => %{age: 23}}

嵌套數據結構

這兩種基於鍵的訪問語法都可以與 Kernel 中的嵌套更新函數和宏一起使用，例如 Kernel.get_in/2 、 Kernel.put_in/3 、 Kernel.update_in/3 、 Kernel.pop_in/2 和 Kernel.get_and_update_in/3 。

例如，要更新另一個Map中的Map：

iex> users = %{"john" => %{age: 27}, "meg" => %{age: 23}}
iex> put_in(users["john"].age, 28)
%{"john" => %{age: 28}, "meg" => %{age: 23}}

該模塊提供了用於遍曆其他結構(如元組和列表)的便利函數。這些函數可用於所有與 Access 相關的函數和 Kernel 中的宏。

例如，給定一個帶有 :name 和 :languages 鍵的用戶映射，下麵是如何深入遍曆映射並將所有語言名稱轉換為大寫：

iex> languages = [
...>   %{name: "elixir", type: :functional},
...>   %{name: "c", type: :procedural}
...> ]
iex> user = %{name: "john", languages: languages}
iex> update_in(user, [:languages, Access.all(), :name], &String.upcase/1)
%{
  name: "john",
  languages: [
    %{name: "ELIXIR", type: :functional},
    %{name: "C", type: :procedural}
  ]
}

請參閱函數 key/1 、 key!/1 、 elem/1 和 all/0 以了解一些可用的訪問器。